トップ > 逆引きで学ぶ ユーザーフォーム&コントロール > 追加章　遊ぶ！楽しむ！ユーザーフォーム > T-02　クリックでイメージを掴み・離す

'フォーム上のイメージをクリックで掴みクリックで離す
Option Explicit

Private strImageName As String

'■フォームイベント(UserForm1)
'+++ Initializeイベント +++
Private Sub UserForm_Initialize()
    'イベント感知用ラベルをフォームにぴったりと重ねる
    With Label_Main
        .Top = 0
        .Left = 0
        .Width = Me.InsideWidth 'クライアント領域幅
        .Height = Me.InsideHeight 'クライアント領域高さ
    End With
End Sub

'■ラベルイベント(Label_Main)
'+++ MouseDownイベント +++
Private Sub Label_Main_MouseDown(ByVal Button As Integer, _
                                 ByVal Shift As Integer, _
                                 ByVal X As Single, _
                                 ByVal Y As Single)
    If strImageName = "" Then
        strImageName = Get_ImageName(Label_Main.Left, Label_Main.Top, X, Y)
    Else
        strImageName = ""
    End If
End Sub

'+++ MouseMoveイベント +++
Private Sub Label_Main_MouseMove(ByVal Button As Integer, _
                                 ByVal Shift As Integer, _
                                 ByVal X As Single, _
                                 ByVal Y As Single)
    If strImageName = "" Then Exit Sub 'イメージ名が空白の場合は抜ける
    With Controls(strImageName)        'イメージの中心がマウスポインタ位置になるように調整
        .Left = Label_Main.Left + X - (.Width / 2)
        .Top = Label_Main.Top + Y - (.Height / 2)
    End With
End Sub

'■関数
'+++ イメージ名取得関数 +++++++++++++++++++++++++++++++++++++++++
'マウスポインタがイメージと重なっている場合にそのイメージ名を返す
'【引数】
'   L：イベント感知ラベルLeft位置
'   T：イベント感知ラベルTop位置
'   X：マウスポインタX位置
'   Y：マウスポインタY位置
'【戻り値】
'   イメージ名
'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Private Function Get_ImageName(ByVal L As Single, ByVal T As Single, _
                               ByVal X As Single, ByVal Y As Single) As String
    Dim objC As MSForms.Control
    For Each objC In Me.Controls
        If TypeName(objC) = "Image" Then 'コントロールタイプ判定
            With objC
                '重なり判定
                If .Left < (L + X) And (L + X) < (.Left + .Width) Then
                    If .Top < (T + Y) And (T + Y) < (.Top + .Height) Then
                        Get_ImageName = .Name
                        Exit Function
                    End If
                End If
            End With
        End If
    Next
End Function

書籍紹介140以上のサンプルファイル付き！

知りたいがすぐわかる！　やりたいがすぐできる！
「Excel VBA 逆引きで学ぶ ユーザーフォーム&コントロール」（Kindle版）
ユーザーフォームを扱えると、VBAでできることが大きく広がります！
本書では、知りたいこと、やりたいことから、逆引きで学びを深められます。

■ 購入：amazon