トップ　>　備忘録　>　フォルダのパス取得・存在確認

'-----------------------------------------------------------------
' フォルダ選択ダイアログボックスでフォルダパスを取得・表示
'-----------------------------------------------------------------
'
'［作成日］2012.11.10　［更新日］2024.11.24
' https://excel.syogyoumujou.com/memorandum/filedialog.html
'-----------------------------------------------------------------
Sub フォルダ選択ダイアログボックス使用例()

    '---------------------------------------
    ' フォルダ選択
    '---------------------------------------
    Dim strFolderPath As String
    '《フォルダパス取得》
    ' ・ 引数1 ： FolderPath    ： 起点となるフォルダパス（省略可能）
    ' ・ 引数2 ： DialogTitle   ： ダイアログボックスタイトル（省略可能）
    ' ・ 引数3 ： ButtonCaption ： ボタン表示テキスト（省略可能）
    strFolderPath = getFolderPath()

    ' フォルダが選択されなかった場合は終了
    If strFolderPath = "" Then Exit Sub
    
    '---------------------------------------
    ' フォルダ名取得（フォルダ存在確認）
    '---------------------------------------
    Dim strFolderName As String
    strFolderName = Dir(strFolderPath, vbDirectory)
    If strFolderName = "" Then
        ' フォルダパスからフォルダ名を取得出来ない場合はフォルダが存在しない
        MsgBox "フォルダが見つかりません", vbExclamation
        Exit Sub
    End If

    '---------------------------------------
    ' フォルダパス表示
    '---------------------------------------
    MsgBox "フォルダ名：" & strFolderName & vbLf & _
           "フォルダパス：" & strFolderPath, , "選択フォルダ"
End Sub

'-----------------------------------------------------------------
' フォルダパス取得
'-----------------------------------------------------------------
'［引数］
'   FolderPath   ：起点となるフォルダパス（既定：""）
'                  ""（空白の文字列）の場合はカレントフォルダが起点
'   DialogTitle  ：ダイアログボックスのタイトル（既定："フォルダ選択"）
'   ButtonCaption：ボタンに表示するテキスト（既定："選択"）
'［戻り値］
'   成功         ：選択したフォルダパス
'  （［キャンセル］ボタンをクリックした場合は空の文字列）
'［作成日］2012.11.10　［更新日］2024.11.24
'-----------------------------------------------------------------
Function getFolderPath(Optional ByVal FolderPath As String = "", _
                       Optional ByVal DialogTitle As String = "フォルダ選択", _
                       Optional ByVal ButtonCaption As String = "選択") As Variant
    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = FolderPath
        .Title = DialogTitle
        .ButtonName = ButtonCaption
        If .Show Then getFolderPath = .SelectedItems(1)
    End With
End Function