トップ　>　備忘録　>　Excel VBA:ファイル名の自動作成

'-----------------------------------------------------------------
'［名前をつけて保存］ダイアログボックスに自動生成したファイル名を設定
'-----------------------------------------------------------------
'
'［作成日］2012.09.27　［更新日］2024.11.26
' https://excel.syogyoumujou.com/memorandum/getsaveasfilename.html
'-----------------------------------------------------------------
Sub ファイル名を自動生成しダイアログボックスの初期ファイル名に設定()
    '---------------------------------------
    ' 定数設定
    '---------------------------------------
    ' 名前を付けて保存ダイアログボックス用
    Const L_FILE_FILTER  As String = "JPG,*.jpg,BMP,*.bmp,TIFF,*.tif"             ' ファイルフィルター
    Const L_FILTER_INDEX As Long = 1                                              ' フィルターインデックス
    Const L_DIALOG_TITLE As String = "画像ファイルの保存名を設定してしてください" ' ダイアログボックスタイトル
    
    ' ベースとなるファイル名
    Const L_BASENAME     As String = "サンプル"

    '---------------------------------------
    ' ベースとなるファイル名表示
    '---------------------------------------
    MsgBox L_BASENAME, vbInformation, "ベースとなるファイル名"
    
    '---------------------------------------
    ' ファイル名自動生成
    '---------------------------------------
    Dim strFileName As String
    '《対象文字列に日時を追加》
    ' ・ 引数1：対象文字列
    ' ・ 引数2：日付追加フラグ（True：日付を追加する　False：日付を追加しない）
    ' ・ 引数3：時刻追加フラグ（True：時刻を追加する　False：時刻を追加しない）
    ' ・ 引数4：対象文字列、日付、時刻の区切り文字（省略した場合は"_"）
    strFileName = addDateAndTimeToString(L_BASENAME, True, False)

    '---------------------------------------
    ' 自動生成されたファイル名表示
    '---------------------------------------
    MsgBox strFileName, vbInformation, "自動生成されたファイル名"

    '---------------------------------------
    ' ダイアログボックス表示
    '---------------------------------------
    Dim varFileName As Variant
    '《名前をつけて保存ダイアログボックス》
    ' ・ 引数1：初期ファイル名
    ' ・ 引数2：ファイルフィルター
    ' ・ 引数3：ファイルインデックス（既定で表示するフィルター文字列の指定）
    ' ・ 引数4：ダイアログボックスタイトル（省略した場合は"名前を付けて保存"）
    ' ・ 引数5：ボタンテキスト（Macintosh用のため使用しない）
    varFileName = Application.GetSaveAsFilename(strFileName, _
                                                L_FILE_FILTER, _
                                                L_FILTER_INDEX, _
                                                L_DIALOG_TITLE)
                                                
    '［キャンセル］ボタンをクリックした場合は抜ける
    If VarType(varFileName) = vbBoolean Then Exit Sub

    '---------------------------------------
    ' ファイルのフルネームを表示
    '---------------------------------------
    MsgBox varFileName, vbInformation, "ファイルのフルネーム"
End Sub

'----------------------------------------------------------------------------------
' 対象文字列に日時を追加
'----------------------------------------------------------------------------------
'［引数］
'   TargetString：対象の文字列 (既定: 空白)
'   AddDateFlg  ：日付の追加設定　True : 追加する (既定)　False: 追加しない
'   AddTimeFlg  ：時刻の追加設定　True : 追加する (既定)　False : 追加しない
'   Separator   ：対象文字列、日付、時刻の区切り文字(既定：アンダーバー)
'［戻り値］
'   対象文字列にプロシージャ実行日付・時刻を追加した文字列
'［作成日］2023.06.05　［更新日］2024.11.26
'----------------------------------------------------------------------------------
Function addDateAndTimeToString(Optional ByVal TargetString As String = "", _
                                Optional ByVal AddDateFlg As Boolean = True, _
                                Optional ByVal AddTimeFlg As Boolean = True, _
                                Optional ByVal Separator As String = "_") As String
    ' 日付の追加
    If AddDateFlg Then
        TargetString = TargetString & Separator & Format$(Date, "yyyymmdd")
    End If
    
    ' 時刻の追加
    If AddTimeFlg Then
        TargetString = TargetString & Separator & Format$(Time, "hhnnss")
    End If

    ' 戻り値の設定
    addDateAndTimeToString = TargetString
End Function