トップ　>　備忘録　>　ファイルのパス取得

'-----------------------------------------------------------------
'［ファイルを開く］ダイアログボックスでファイルパスを取得・表示
'-----------------------------------------------------------------
'
'［作成日］2012.09.27　［更新日］2024.11.22
' https://excel.syogyoumujou.com/memorandum/getopenfilename.html
'-----------------------------------------------------------------
Sub ファイルを開くダイアログボックス使用例()
    '---------------------------------------
    ' 定数設定
    '---------------------------------------
    Const L_FILE_FILTER  As String = "画像タイプ１,*.bmp;*.jpg;*.gif," & _
                                     "画像タイプ２,*.png"                 ' ファイルフィルター
    Const L_FILTER_INDEX As Long = 1                                      ' フィルターインデックス
    Const L_DIALOG_TITLE As String = "画像ファイルを選択してください"     ' ダイアログボックスタイトル
    Const L_MULTI_SELECT As Boolean = True                                ' 複数選択の設定
    
    '---------------------------------------
    ' カレントフォルダをデスクトップに設定
    '---------------------------------------
    ' デスクトップフォルダパス取得
    Dim strDesktopPath As String
    strDesktopPath = CreateObject("WScript.Shell").SpecialFolders("Desktop")
    ' ドライブの設定
    ChDrive Left$(strDesktopPath, 1)
    ' カレントフォルダの設定
    ChDir strDesktopPath
    
    '---------------------------------------
    ' ファイルを選択
    '---------------------------------------
    Dim varFilePath As Variant
    Dim strFilePath As String
    '《ファイル選択ダイアログボックス》
    ' ・ 引数1：ファイルフィルター
    ' ・ 引数2：ファイルインデックス（既定で表示するフィルター文字列の指定）
    ' ・ 引数3：ダイアログボックスタイトル
    ' ・ 引数4：ボタンテキスト（Macintosh用）
    ' ・ 引数5：複数選択の設定（True：複数選択可　False：複数選択不可）
    varFilePath = Application.GetOpenFilename(L_FILE_FILTER, _
                                              L_FILTER_INDEX, _
                                              L_DIALOG_TITLE, _
                                              , _
                                              L_MULTI_SELECT)
    
    '［キャンセル］ボタンをクリックした場合は抜ける
    If VarType(varFilePath) = vbBoolean Then Exit Sub

    ' 引数5 複数選択の設定（MultiSelect）が True の場合 返り値は配列となる
    If IsArray(varFilePath) Then
        ' 配列の各要素の文字列を結合し文字列型変数に代入
        strFilePath = Join$(varFilePath, vbLf)
    Else
        ' 返り値を文字列型変数に代入
        strFilePath = varFilePath
    End If

    '---------------------------------------
    ' 結果表示
    '---------------------------------------
    MsgBox strFilePath, , "選択したファイルのパス"
End Sub