トップ　>　備忘録　>　文字列←→16進数←→2進数の相互変換

'----------------------------------------------------------
' 文字列 ←→ 16進数 ←→ 2進数の相互変換マクロ
'----------------------------------------------------------
Sub Interconversion_Main()
    ' 変換対象文字列
    Dim str As String
    str = "坂江 保"
    MsgBox str, , "変換対象文字列"

    ' 文字列 → 16進数
    Dim strHexString As String
    strHexString = convertStringToHex(str)
    MsgBox strHexString, , "文字列 → 16進数"
    
    ' 16進数 → 2 進数
    Dim strBinaryString As String
    strBinaryString = convertHexToBinary(strHexString)
    MsgBox strBinaryString, , "16進数 → 2 進数"
    
    ' 2 進数 → 16進数
    strHexString = convertBinaryToHex(strBinaryString)
    MsgBox strHexString, , "2 進数 → 16進数"
    
    ' 16進数 → 文字列
    str = convertHexToString(strHexString)
    MsgBox str, , "16進数 → 文字列"
End Sub

'----------------------------------------------------------
' 文字列を16進数に変換する関数
'----------------------------------------------------------
'［引数］
'   strTarget：対象文字列
'［戻り値］
'   各文字を16進数に変換した値を半角スペースで連結した文字列
'   引数が空の文字列の場合は空の文字列
'［作成日］2013.09.23　［更新日］2024.04.20
'----------------------------------------------------------
Function convertStringToHex(ByVal strTarget As String) As String
    If Len(strTarget) = 0 Then Exit Function
    
    Dim i As Long
    ReDim strHex(1 To Len(strTarget)) As String
    For i = 1 To Len(strTarget)
        strHex(i) = Hex$(Asc(Mid$(strTarget, i, 1)))
    Next
    
    convertStringToHex = Join$(strHex, " ")
End Function

'----------------------------------------------------------
' 16進数を2進数に変換する関数
'----------------------------------------------------------
'［引数］
'   strHex：16進数の文字列
'［戻り値］
'   16進数を2進数に変換した値を半角スペースで連結した文字列
'   引数が空の文字列の場合は空の文字列
'［作成日］2013.09.23　［更新日］2024.04.20
'----------------------------------------------------------
Function convertHexToBinary(ByVal strHex As String) As String
    If Len(strHex) = 0 Then Exit Function
    
    '---------------------------------------
    ' 0～15の2進数を配列として設定
    '---------------------------------------
    Dim varBinaryNumber As Variant
    varBinaryNumber = Array("0000", "0001", "0010", "0011", "0100", "0101", "0110", "0111", _
                            "1000", "1001", "1010", "1011", "1100", "1101", "1110", "1111")
    '---------------------------------------
    ' 16進数を2進数に変換
    '---------------------------------------
    Dim i As Long
    ReDim strBinary(1 To Len(strHex)) As String
    For i = 1 To Len(strHex)
        If StrComp(Mid$(strHex, i, 1), " ") = 0 Then
            strBinary(i) = " "
        Else
            strBinary(i) = varBinaryNumber(Val("&h" & Mid$(strHex, i, 1)))
        End If
    Next
    
    convertHexToBinary = Join$(strBinary, vbNullString)
End Function

'----------------------------------------------------------
' 2進数を16進数に変換する関数
'----------------------------------------------------------
'［引数］
'   strBinary：2進数の文字列
'［戻り値］
'   2進数を16進数に変換した値を半角スペースで連結した文字列
'   引数が空の文字列の場合は空の文字列
'［作成日］2013.09.23　［更新日］2024.04.20
'----------------------------------------------------------
Function convertBinaryToHex(ByVal strBinary As String) As String
    If Len(strBinary) = 0 Then Exit Function
    
    '---------------------------------------
    ' 0～15の2進数を配列として設定
    '---------------------------------------
    Dim varBinaryNumber As Variant
    varBinaryNumber = Array("0000", "0001", "0010", "0011", "0100", "0101", "0110", "0111", _
                            "1000", "1001", "1010", "1011", "1100", "1101", "1110", "1111")

    '---------------------------------------
    ' コレクションオブジェクトに2進数を設定
    '---------------------------------------
    Dim i As Long
    ' 2進数を「キー」とし、対応する16進数「0～F」を「アイテム」として登録
    Dim colHexAndBinary As New Collection
    For i = 0 To 15
        colHexAndBinary.Add CStr(Hex$(i)), varBinaryNumber(i)
    Next

    '---------------------------------------
    ' 2進数を16進数に変換
    '---------------------------------------
    ' 2進数の文字列をスペースで分割し配列として設定
    Dim varArray As Variant
    If InStr(1, strBinary, " ") Then
        varArray = Split(strBinary, " ")
    Else
        ReDim varArray(0)
        varArray(0) = strBinary
    End If
    
    ' 2進数を4bitずつ16進数に変換
    Dim j As Long
    For i = 0 To UBound(varArray)
        ReDim strHext(1 To (Len(varArray(i)) / 4)) As String
        For j = 1 To (Len(varArray(i)) / 4)
            strHext(j) = colHexAndBinary.Item(Mid$(varArray(i), (j - 1) * 4 + 1, 4))
        Next
        varArray(i) = Join$(strHext, vbNullString)
    Next

    convertBinaryToHex = Join$(varArray, " ")
End Function

'----------------------------------------------------------
' 16進数を文字列に変換する関数
'----------------------------------------------------------
'［引数］
'   strHex：16進数の文字列
'［戻り値］
'   16進数から変換した文字を連結した文字列
'   引数が空の文字列の場合は空の文字列
'［作成日］2013.09.23　［更新日］2024.04.20
'----------------------------------------------------------
Function convertHexToString(ByVal strHex As String) As String
    If Len(strHex) = 0 Then Exit Function
    
    '---------------------------------------
    ' 16進数を文字列に変換
    '---------------------------------------
    ' 16進数の文字列をスペースで分割し配列として設定
    Dim varArray As Variant
    If InStr(1, strHex, " ", vbTextCompare) Then
        varArray = Split(strHex, " ")
    Else
        ReDim varArray(0)
        varArray(0) = strHex
    End If
    
    Dim i As Long
    ReDim strChar(UBound(varArray)) As String
    For i = 0 To UBound(varArray)
        strChar(i) = Chr$(Val("&h" & varArray(i)))
    Next

    convertHexToString = Join$(strChar, vbNullString)
End Function