トップ　>　汎用コード　>　音楽の再生

' ***（宣言セクションに記述）***
'-------------------------------
' Win32API
'《MCI デバイスにコマンド文字列を送信》
' https://learn.microsoft.com/ja-jp/previous-versions//dd757161(v=vs.85)
Declare PtrSafe Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" ( _
                                        ByVal lpstrCommand As String, _
                                        ByVal lpstrReturnString As String, _
                                        ByVal uReturnLength As Long, _
                                        ByVal hwndCallback As LongPtr) As Long
'-------------------------------
' 定数
'-------------------------------
' ファイル読み込み時に設定する名前
Private Const L_FILENAME As String = "sample"
' ***（ここまで）***

'-----------------------------------------------------------------
' 音声ファイルをダイアログボックスで選択し読み込む
'-----------------------------------------------------------------
'［作成日］2016.05.01　［更新日］2025.03.15
' https://excel.syogyoumujou.com/vba/mci.html
'-----------------------------------------------------------------
Sub 音声ファイルを読み込む()
    
    '---------------------------------------
    ' ファイルを選択
    '---------------------------------------
    Dim varFilePath As Variant
    '《ファイル選択ダイアログボックス》
    ' ・ 引数1：ファイルフィルター
    ' ・ 引数2：ファイルインデックス（既定で表示するフィルター文字列の指定）
    ' ・ 引数3：ダイアログボックスタイトル
    ' ・ 引数4：ボタンテキスト（Macintosh用）
    ' ・ 引数5：複数選択の設定（True：複数選択可　False：複数選択不可）
    varFilePath = Application.GetOpenFilename("音声ファイル,*.wav;*.mid;*.mp3;*.wma", _
                                              1, _
                                              "音声ファイルを選択してください", _
                                              , _
                                              False)

    '［キャンセル］ボタンをクリックした場合は抜ける
    If VarType(varFilePath) = vbBoolean Then Exit Sub
    
    ' 取得したファイルパスが配列の場合は最初のファイルパスを対象とする
    Dim strFilePath As String
    If IsArray(varFilePath) Then
        strFilePath = varFilePath(0)
    Else
        strFilePath = varFilePath
    End If

    '---------------------------------------
    ' 音声ファイルをメモリに読み込み
    '---------------------------------------
    Dim lngReturn  As Long
    Dim strCommand As String
    
    ' ファイルパスをダブルクォーテーションで括る
    '（ファイルパスに空白があった場合の対応）
    strFilePath = """" & strFilePath & """"
    
    ' 送信用のコマンド文字列作成
    strCommand = "Open " & strFilePath & " alias " & L_FILENAME
    
    '《MCI デバイスにコマンド文字列を送信》
    ' ・ 引数1：実行する MCI コマンド文字列
    ' ・ 引数2：結果を格納するためのバッファ（不要の場合は vbNullString を設定）
    ' ・ 引数3：引数2のバッファサイズ（文字数）（0 にすると 引数2 は使用されない）
    ' ・ 引数4：コールバック通知を受け取るウィンドウハンドル（通常 0）
    '   戻り値：成功：0　エラー：0以外
    lngReturn = mciSendString(strCommand, vbNullString, 0, 0)
    
    If lngReturn = 0 Then
        MsgBox "音声ファイルをメモリに読み込みました", vbInformation
    Else
        MsgBox "音声ファイルの読み込みに失敗しました", vbExclamation
    End If
End Sub

'-----------------------------------------------------------------
'   読み込んだ音楽を再生する
'-----------------------------------------------------------------
Sub 再生()
    Call mciSendString("Play " & L_FILENAME & " from 0", vbNullString, 0, 0)
End Sub

'-----------------------------------------------------------------
'   再生中の音楽を停止する
'-----------------------------------------------------------------
Sub 停止()
    Call mciSendString("Stop " & L_FILENAME, vbNullString, 0, 0)
End Sub

'-----------------------------------------------------------------
'   再生中の音楽を一時停止する
'-----------------------------------------------------------------
Sub 一時停止()
    Call mciSendString("Pause " & L_FILENAME, vbNullString, 0, 0)
End Sub

'-----------------------------------------------------------------
'   一時停止中の音楽を再生する
'-----------------------------------------------------------------
Sub 一時停止解除()
    Call mciSendString("Resume " & L_FILENAME, vbNullString, 0, 0)
End Sub

'*****************************************************************
' Excelを閉じる前に必ず実行してください
'*****************************************************************
Sub 音声ファイルをメモリからクリア()
    Call mciSendString("Close All", vbNullString, 0, 0)
End Sub