トップ　>　汎用コード　>　特定データが含まれる行(列)を一括削除

Sub FIND_AND_RCselect() '対象：アクティブシート
    Dim varArray   As Variant
    Dim v          As Variant
    Dim strAddress As String
    Dim rngFnd     As Range
    Dim rngUni     As Range
    
    varArray = Array("りんご", "リンゴ") '検索文字列
    
    For Each v In varArray
        Set rngFnd = Cells.Find(What:=v,  _
                                LookIn:=xlValues,  _
                                LookAt:=xlPart,  _
                                SearchOrder:=xlByRows,  _
                                MatchCase:=False,  _
                                MatchByte:=False) '検索　1周目「りんご」2周目「リンゴ」
        If Not rngFnd Is Nothing Then   '
            strAddress = rngFnd.Address '最初に検索一致したセルの番地格納
            If rngUni Is Nothing Then Set rngUni = rngFnd
            Do
                Set rngUni = Union(rngUni, rngFnd)  'セルを集合
                Set rngFnd = Cells.FindNext(rngFnd) '次の一致セルを検索
            Loop Until strAddress = rngFnd.Address  'セルのアドレスが一致したらループを抜ける
        End If
    Next
    
    If Not rngUni Is Nothing Then
        rngUni.Interior.ColorIndex = 6
        If MsgBox("行：「はい」　列：「いいえ」", vbYesNo, "行を選択しますか？") = vbYes Then
            Union(rngUni.EntireRow, rngUni.EntireRow).Select '行選択
        Else
            Union(rngUni.EntireColumn, rngUni.EntireColumn).Select '列選択
        End If
    End If
End Sub