トップ　>　汎用コード　>　値を変更しながらの連続PDF出力

'+++ 値を順に変えてのPDF出力 +++
'https://excel.syogyoumujou.com/vba/output_pdf.html
Sub ContinuousOutputAsPDF()

    '定数
    Const START_NUM  As Long = 1          '開始番号
    Const END_NUM    As Long = 40         '終了番号
    Const C_STEP     As Long = 1          '間隔
    Const C_ADDRESS  As String = "A1"     'セル番地
    Const C_FILENAME As String = "Sample" '出力ファイルの基準名
    
    'フォルダの選択
    MsgBox "出力先のフォルダを選択してください", vbInformation
    Dim strFolderPath As String
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show Then
            strFolderPath = .SelectedItems(1)
        Else
            Exit Sub
        End If
    End With
    
    'アクティブシートをPDFとして出力
    Dim strFileName As String
    strFileName = strFolderPath & "\" & C_FILENAME
    Application.ScreenUpdating = False
    With ActiveSheet
        Dim i As Long
        For i = START_NUM To END_NUM Step C_STEP
            .Range(C_ADDRESS).Value = i
            .ExportAsFixedFormat _
                Type:=xlTypePDF, _
                Filename:=strFileName & Format$(i, "000"), _
                OpenAfterPublish:=False
        Next
    End With
    Application.ScreenUpdating = True
    
    'フォルダを開く
    Call Shell("C:\Windows\Explorer.exe " & strFolderPath, vbNormalFocus)
End Sub

【書籍紹介】知りたいがすぐわかる！　やりたいがすぐできる！
「Excel VBA 逆引きで学ぶ ユーザーフォーム&コントロール」（Kindle版）
ユーザーフォームを扱えると、VBAでできることが大きく広がります！
本書では、知りたいこと、やりたいことから、逆引きで学びを深められます。
140以上のサンプルファイル付き！