トップ　>　汎用コード　>　テキスト一括置換

'2021/4/7更新
Const conBF As String = "田中" '置換前文字列
Const conAF As String = "中田" '置換後文字列
Const conTX As String = "html" 'テキストファイル種類（txt,html等）

Sub All_Text_Replace() 'メイン
    Dim strDirPath As String
    strDirPath = Search_Directory()                    'フォルダの参照
    If Len(strDirPath) = 0 Then Exit Sub
    If Dir(strDirPath, vbDirectory) = "" Then Exit Sub 'フォルダの存在確認
    Call Search_File(strDirPath)
End Sub

Private Function Search_Directory() As String 'フォルダの参照
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = True Then Search_Directory = .SelectedItems(1)
    End With
End Function

Private Sub Search_File(ByVal strPath As String) 'フォルダ内ファイル検索
    Dim strBuf    As String
    Dim strTarget As String
    strPath = strPath & Application.PathSeparator
    strTarget = Dir(strPath & "*." & conTX)
    If strTarget = "" Then Exit Sub
    With CreateObject("ADODB.Stream")
        .Charset = "UTF-8"
        Do
            .Open
            .LoadFromFile strPath & strTarget
            strBuf = .ReadText 'テキスト読み込み
            .Close
            strBuf = Replace$(strBuf, conBF, conAF) '置換処理
            Call Write_Text(strBuf, strPath & strTarget) 'テキスト書き込み
            strTarget = Dir()
        Loop Until strTarget = ""
    End With
    strTarget = Dir("")
End Sub

Private Sub Write_Text(ByVal strText As String, ByVal strFileP As String)
    With CreateObject("ADODB.Stream")
        .Charset = "UTF-8"
        .Open
        .WriteText strText 'テキスト書き込み
        .SaveToFile strFileP, 2
        .Close
    End With
End Sub