トップ　>　汎用コード　>　複数の単語を一括置換

Sub Sample_Replace_1() 'アクティブシート対象
    Dim varSearch As Variant
    Dim varAfRepl As Variant

    '要素毎に対【例】富川→富山、神田川→神奈川、チーバ→千葉、君→県
    varSearch = Array("富川", "神田川", "チーバ", "君")  '検索文字列
    varAfRepl = Array("富山", "神奈川", "千葉", "県")    '置換文字列
    
    Call ReplacementMain(ActiveSheet, varSearch, varAfRepl)
End Sub

Sub Sample_Replace_2() 'アクティブブックの全シート対象
    Dim varSearch As Variant
    Dim varAfRepl As Variant

    '要素毎に対
    varSearch = Array("富川", "神田川", "チーバ", "君")  '検索文字列
    varAfRepl = Array("富山", "神奈川", "千葉", "県")    '置換文字列
    
    Dim WS As Worksheet
    For Each WS In ActiveWorkbook.Worksheets
        Call ReplacementMain(WS, varSearch, varAfRepl)
    Next
End Sub

Private Sub ReplacementMain(Sh As Worksheet, varSC, varAR) '置換メイン処理
    Dim i As Long
    For i = LBound(varSC) To UBound(varSC)
        Sh.Cells.Replace What:=varSC(i), _
                         Replacement:=varAR(i), _
                         LookAt:=xlPart, _
                         SearchOrder:=xlByColumns, _
                         MatchCase:=False, _
                         MatchByte:=False
    Next
End Sub